返回首页
当前位置: 主页 > Excel教程 > Excel VBA教程 >

Excel将区域中的值按出现次数的多少提取到一列

时间:2013-08-18 01:56来源:Office教程学习网 www.office68.com编辑:麦田守望者

对于一个包含重复数值的区域,要将其中的数值按出现次数的多少提取到一列,通常可以用包含MODE函数的数组公式。例如数值区域为A1:E10,要将其中的数值提取到G列,如图。

用MODE函数按出现次数提取区域中的数值示例 

在G2中输入:

=MODE(IF(COUNTIF($G$1:G1,A$1:E$10)=0,A$1:E$10))

公式输入完毕按Ctrl+Shift+Enter结束,然后拖动填充柄向下填充公式,直到出现“#N/A”为止。

受MODE函数的限制,该公式仅对数值有效,且不能提取只出现一次的数值。要将区域中所有的数据按出现次数提取到一列,可用VBA代码来实现。如将下图A1:E10区域中的文本按出现次数多少提取到G列:

VBA按出现次数提取区域中的文本示例

按Alt+F11,打开VBA编辑器,在代码窗口中输入下列代码并运行,即可G列得到按出现次数降序排序的文本,在H列得到对应文本的出现次数。

Sub 按出现次数排序()
Dim d As Object
Dim Arr
Dim i As Integer, j As Integer
Application.ScreenUpdating = False

'提取不重复值并计算出现次数
Set d = CreateObject("Scripting.Dictionary")
Arr = Range("A1:E10")
For i = 1 To UBound(Arr, 1)
For j = 1 To UBound(Arr, 2)
If Not d.Exists(Arr(i, j)) Then
d.Add Arr(i, j), 1
Else
d.Item(Arr(i, j)) = d.Item(Arr(i, j)) + 1
End If
Next
Next

'输出并排序
Range("G2").Resize(d.Count) = Application.Transpose(d.keys)
Range("H2").Resize(d.Count) = Application.Transpose(d.items)
Range("G2:H2").Resize(d.Count).Sort key1:=Range("H2"), Order1:=xlDescending

Set d = Nothing
Application.ScreenUpdating = True
End Sub

说明:如果文本出现的次数相同,将按先行后列的顺序依次提取。

顶一下
(2)
100%
踩一下
(0)
0%
标签(Tag):excel excel2013 excel2007 excel2003 excel2010 excel技巧 excel教程 excel实例教程
------分隔线----------------------------
------分隔线----------------------------
发表评论
请自觉遵守互联网相关的政策法规,严禁发布色情、暴力、反动的言论。
评价:
表情:
验证码:点击我更换图片
猜你感兴趣